How would I stop my shape from moving using keypressed?

How would I make my shape stop every time I press the spacebar and move when I press the spacebar again.

To pause and resume updating the position you would need to create a separate variable to keep track of this state change: a boolean value is perfect in this case.

e.g.

boolean shouldSquareUpdate = true;

You can use keyPressed() to listen for key changes in Processing:

void draw(){
}
void keyPressed(){
  println("key: " + key + " keyCode: " + keyCode);
}

The next part is toggling the boolean value:

• if the value was true, set it to false
• if it was false, set it to true

e.g.

void keyPressed(){
  // toggle boolean (if true, set it to false, if false, set it to true)
  if(shouldSquareUpdate == true){
    shouldSquareUpdate = false;
  }else{
    shouldSquareUpdate = true;
  }
}

This can be more elegantly be solved with the logical NOT operator, which essentially flips the state of the boolean:

void keyPressed(){
  // toggle boolean (if true, set it to false, if false, set it to true)
  shouldSquareUpdate = !shouldSquareUpdate;
}

Finally, you would use this condition to determine if the y value should be updated (or not):

// update only if value is true
  if(shouldSquareUpdate){
    y += dy;
  }

The full sketch would like so:

int x = 0;
int y = 0;

int dy = 1;

boolean shouldSquareUpdate = true;

void setup() {
  size(1280, 720);
  surface.setResizable(true);
}

void draw() {
  background(240, 240, 240);
  fill(255, 147, 79);
  rect(x, y, 90, 90);
  // update only if value is true
  if(shouldSquareUpdate){
    y += dy;
  }
  if(y + 90 > height || y < 0) {
    dy *= -1;
  }
}

void keyPressed(){
  // toggle boolean (if true, set it to false, if false, set it to true)
  shouldSquareUpdate = !shouldSquareUpdate;
}

Regarding

> how would I make my square move in 8 equal steps?

That should be a matter of simply updating the dy value which you currently set a 1 (pixel per frame) to be an 8th of the total travel distance (height):

e.g.

// in setup()
dy = height / 8;

Bare in mind that 720 / 8 = 90 pixels per frame, with 60 frames a second that would be 5400 pixels per second: waaay to fast for the motion be legible.

You can use the same principle to maybe move the box in 32 equal steps ?
e.g.

void setup() {
  size(1280, 720);
  surface.setResizable(true);
  // make square move in 32 equal steps: increment 32th of the total height
  dy = height / 32;
}