Copy data from combobox to a table, in sucessive rows

I'm working with three ComboBox'es that display certain data. When I hit a button, I want to send the selected data to a given table, which is located in a different worksheet from where the code is executed. This is what I have, so far:

Private Sub BotonAgregar_Click()

Dim ws As Worksheet
Set ws = ThisWorkbook.Sheets("_items")

ws.Cells(2, 1) = CajaMes
ws.Cells(2, 2) = CajaConcepto
ws.Cells(2, 3) = CajaValor
           
CajaMes = Empty
CajaConcepto = Empty
CajaValor = Empty

End Sub

In this code, I'm successfully sending all three fields data to tab _items in the desired cells, but just the fist instance. If I want send further data, the first row is being replaced. I want to send everything to one row under the next one. Any help?

The problem is that you are not updating the row number to send the data to, that's why it keeps overwriting the same row's cells.

There are many ways to get the last empty row in a table, depending on how your data is set up, but below is a simple example:

Private Sub BotonAgregar_Click()

Dim ws As Worksheet
Set ws = ThisWorkbook.Sheets("_items")

Dim LastRow As Long
'getting the last row, nb. we add 1 to the LastRow so we put the data in the next empty line
LastRow = ws.Cells(ws.Rows.Count, 1).End(xlUp).Row + 1
If LastRow < 2 Then LastRow = 2 'just making sure it starts at 2 and not lower

ws.Cells(LastRow, 1) = Me.CajaMes.value
ws.Cells(LastRow, 2) = Me.CajaConcepto.value
ws.Cells(LastRow, 3) = Me.CajaValor.value

Me.CajaMes.value = Null
Me.CajaConcepto.value = Null
Me.CajaValor.value = Null

End Sub

This should now do what you require

if those Caja... are your combo boxes on a UserForm and you use Empty to make them not showing any item, test this code, please:

Dim ws As Worksheet
Set ws = ThisWorkbook.Sheets("_items")

ws.Cells(2, 1).value = Me.CajaMes.value
ws.Cells(2, 2).value = Me.CajaConcepto.value
ws.Cells(2, 3).value = Me.CajaValor.value

Me.CajaMes.ListIndex = -1
Me.CajaConcepto.ListIndex = -1
Me.CajaValor.ListIndex = -1

But, if no combo value (no any item selected) the function will return an error at that specific line...

If your combo boxes are ActiveX type, staying on a page, try the next code:

Dim ws As Worksheet, cbCM As ComboBox, cbCon As ComboBox, cbCjV As ComboBox
    Set ws = ActiveSheet
      Set cbCM = ws.OLEObjects("CajaMes").Object
      Set cbCon = ws.OLEObjects("CajaConcepto").Object
      Set cbCjV = ws.OLEObjects("CajaValor").Object
    ws.Cells(2, 1).value = cbCM.value
    ws.Cells(2, 2).value = cbCon.value
    ws.Cells(2, 3).value = cbCjV.value
    
    cbCM.ListIndex = -1
    cbCon.ListIndex = -1
    cbCjV.ListIndex = -1