How to use value of environment variable in project file?

I'm trying to add a homebrew library to another project.

Following a suggestion in another answer that I now cannot find, I have created xyz.prf in mkspecs/features and have added

    config += xyz

to my project file.

xyz.prf contains

INCLUDEPATH += $XYZ_INC
DEPENDPATH += $XYZ_INC

win32:CONFIG(release, debug|release): LIBS += -L$XYZ_DIR -llibxyz
else:win32:CONFIG(debug, debug|release): LIBS += -L$XYZ_DIR -llibxyz
else:unix: LIBS += -L$XYZ_DIR -llibxyz

I've defined XYZ_INC and XYZ_DIR in the build configuration and have run qmake as often as needed.

However, when I try to build, there's an error at link time.

g++ -Wl,-rpath,/opt/Qt/5.12.5/gcc_64/lib -o someprogram someprogram.o   -L/home/alan/work/myStuff/sqlPrettyPrinter/v3/build-SQLPPv3-Desktop_Qt_5_12_5_GCC_64bit-Debug/test/test_collationname/../../libsqlpp/ -llibsqlpp -LYZ_DIR -llibxyz /opt/Qt/5.12.5/gcc_64/lib/libQt5Test.so /opt/Qt/5.12.5/gcc_64/lib/libQt5Core.so -lpthread   
/usr/bin/ld: cannot find -llibxyz

Now, looking at the g++ command line, I see -LYZ_DIR which explains why ld can't find libxyz - it ought to be -L$XYZ_DIR or -L<whatever XYZ_DIR expands to>.

I've tried every combination of $ or $$ and XYZ_DIR, {XYZ_DIR} or (XYZ_DIR). None work and all but the above combination end up generating `-L' (without any directory).

What's the right syntax to generate what I need?

Sorry - this question has ended up longer than intended; however, I can't think of a way that it can sensibly be shortened.

As the docs points out, $$(...) must be used to obtain the environment variables:

>Variables can be used to store the contents of environment variables. These can be evaluated at the time when qmake is run, or included in the generated Makefile for evaluation when the project is built.

> To obtain the contents of an environment value when qmake is run, use
> the $$(...) operator:
>
> DESTDIR = $$(PWD)
> message(The project will be installed in $$DESTDIR)

xyz.prf

INCLUDEPATH += $$(XYZ_INC)
DEPENDPATH += $$(XYZ_INC)

win32:CONFIG(release, debug|release): LIBS += -L$$(XYZ_DIR) -llibxyz
else:win32:CONFIG(debug, debug|release): LIBS += -L$$(XYZ_DIR) -llibxyz
else:unix: LIBS += -L$$(XYZ_DIR) -llibxyz

With the previous code element it is applied only when qmake is executed, but if you want it to be executed with the make command you must use $(...) as indicated by the docs:

> To obtain the contents of an environment value at the time when the
> generated Makefile is processed, use the $(...) operator:
>
> DESTDIR = $$(PWD)
> message(The project will be installed in $$DESTDIR)
>
> DESTDIR = $(PWD)
> message(The project will be installed in the value of PWD)
> message(when the Makefile is processed.)

xyz.prf

INCLUDEPATH += $(XYZ_INC)
DEPENDPATH += $(XYZ_INC)

win32:CONFIG(release, debug|release): LIBS += -L$(XYZ_DIR) -llibxyz
else:win32:CONFIG(debug, debug|release): LIBS += -L$(XYZ_DIR) -llibxyz
else:unix: LIBS += -L$(XYZ_DIR) -llibxyz